Formula umum
=DATEDIF(birthdate,TODAY(),"y")
Ringkasan
Untuk menghitung usia dari tanggal lahir, Anda dapat menggunakan fungsi DATEDIF bersama dengan fungsi TODAY. Dalam contoh yang diperlihatkan, rumus di sel E5, disalin, adalah:
=DATEDIF(D5,TODAY(),"y")
Karena TODAY selalu mengembalikan tanggal sekarang, rumus akan terus menghitung usia yang benar di masa mendatang.
Penjelasan
Fungsi DATEDIF (Date + Dif) adalah sedikit anomali di Excel. Fungsi kompatibilitas yang berasal dari Lotus 1-2-3, Excel tidak akan membantu memberikan argumen saat fungsi tersebut dimasukkan. Namun, DATEDIF berfungsi di semua versi modern Excel dan merupakan fungsi yang berguna untuk menghitung interval antara dua tanggal dalam tahun, bulan, dan hari.
Dalam contoh yang ditunjukkan, tujuannya adalah menghitung usia dalam tahun. Rumus dalam E5 adalah:
=DATEDIF(D5,TODAY(),"y")
Dua argumen pertama untuk DATEDIF adalah start_date dan end_date. Tanggal mulai berasal dari sel D5 (15 Mei 2001) dalam contoh. Tanggal akhir dibuat dengan fungsi TODAY. TODAY selalu mengembalikan tanggal saat ini di Excel. Pada tulisan ini, tanggal saat ini adalah 24 November 2020. Argumen terakhir di DATEDIF menentukan satuan waktu. Fungsi DATEDIF mendukung beberapa opsi di sini, tetapi untuk contoh ini tujuannya adalah usia dalam setahun penuh, jadi kami menggunakan "y" untuk menentukan tahun lengkap.
Pada titik ini, kita dapat menulis ulang rumusnya seperti di bawah ini:
=DATEDIF("15-May-2001","24-Nov-2020", "y")
Karena tanggal Excel sebenarnya adalah nomor seri, nilai mentahnya adalah:
=DATEDIF(37026,44159,"y")
Dengan masukan ini, DATEDIF mengembalikan 19 sebagai hasil akhir.
Usia pada tanggal tertentu
Untuk menghitung usia pada tanggal tertentu, ganti fungsi TODAY dengan tanggal target. Cara mudah dan aman untuk memasukkan tanggal tertentu ke dalam rumus secara manual adalah dengan menggunakan fungsi DATE. Misalnya, untuk menghitung usia per 1 Januari 2021, Anda dapat menggunakan rumus seperti ini:
=DATEDIF(D5,DATE(2022,1,1),"y") // returns 20
Formula ini akan mengembalikan usia Michael Chang pada 1 Januari 2022, yaitu 20.
Dewasa atau di Bawah Umur
Untuk memeriksa tanggal lahir dan mengembalikan "Kecil" atau "Dewasa", Anda dapat menggabungkan rumus dalam fungsi IF seperti:
=IF(DATEDIF(D5,TODAY(),"y")<18,"Minor","Adult")
Rumus di atas adalah contoh penumpukan. Gantikan usia 18 tahun dengan usia berapa pun yang sesuai.
Usia dalam tahun, bulan, dan hari
Untuk menghitung usia dalam tahun, bulan, dan hari, gunakan tiga contoh DATEDIF seperti ini:
=DATEDIF(A1,TODAY(),"y")&"y "&DATEDIF(A1,TODAY(),"ym")&"m "&DATEDIF(A1,TODAY(),"md")&"d"
Contoh pertama DATEDIF mengembalikan tahun, contoh kedua menghasilkan bulan, dan contoh ketiga mengembalikan hari. Ini adalah contoh penggabungan, dan hasilnya adalah string teks seperti ini:
19y 6m 9d
Perhatikan tanggal mulai dan akhir tetap sama di ketiga DATEDIF; hanya unit yang diubah.
YEARFRAC dengan INT
Opsi lain untuk menghitung usia dari tanggal lahir menggunakan fungsi YEARFRAC bersama dengan fungsi INT dalam rumus seperti ini:
=INT(YEARFRAC(D5,TODAY()))
YEARFRAC menghitung angka desimal yang mewakili pecahan tahun antara dua tanggal. Untuk menghitung pecahan tahun sebagai nilai desimal, Excel menggunakan hari di antara dua tanggal. Seperti di atas, tanggal lahir diberikan sebagai start_date dari sel D5, dan tanggal hari ini disediakan sebagai tanggal_akhir, berkat fungsi TODAY.
Dengan tanggal saat ini 24 November 2020, hasil dari YEARFRAC untuk Michael Chang adalah:
19.5290896646133
Selanjutnya, fungsi INT mengambil alih dan membulatkan angka itu ke nilai integer, yaitu angka 19.
=INT(19.5290896646133) // returns 19
Rumus ini tampak sangat logis dan berfungsi dengan baik dalam banyak kasus. Namun, YEARFRAC dapat mengembalikan angka yang salah pada tanggal hari jadi (ulang tahun). Saya tidak yakin persis mengapa ini terjadi, tetapi ini terkait dengan bagaimana YEARFRAC menggunakan hari untuk menentukan tahun pecahan, yang dikendalikan oleh argumen basis. Sebagai contoh:
=YEARFRAC(DATE(1960,6,30),DATE(1962,6,30),1) // 1.998, should be 2 =YEARFRAC(DATE(1960,3,3),DATE(1964,3,3),1) // 3.998, should be 4
Intinya adalah bahwa rumus DATEDIF tanggal adalah pilihan yang lebih aman dan mudah bila tujuannya adalah untuk melaporkan usia dalam setahun penuh.
