Formula umum
=IFERROR(FORMULA(),"message")
Ringkasan
Kesalahan # N / A biasanya muncul ketika sesuatu tidak dapat ditemukan atau diidentifikasi. Namun, kesalahan # N / A juga dapat disebabkan oleh karakter spasi ekstra, salah eja, atau tabel pencarian yang tidak lengkap. Fungsi yang paling sering dipengaruhi oleh kesalahan # N / A adalah fungsi pencarian klasik, termasuk VLOOKUP, HLOOKUP, LOOKUP, dan MATCH. Lihat di bawah untuk informasi lebih lanjut dan langkah-langkah penyelesaian.
Penjelasan
Tentang kesalahan # N / A
Kesalahan # N / A muncul ketika sesuatu tidak dapat ditemukan atau diidentifikasi. Ini sering kali merupakan kesalahan yang berguna, karena memberi tahu Anda bahwa ada sesuatu yang penting yang hilang - produk belum tersedia, nama karyawan salah eja, opsi warna yang tidak ada, dll.
Namun, kesalahan # N / A juga dapat disebabkan oleh karakter spasi ekstra, salah eja, atau tabel pencarian yang tidak lengkap. Fungsi yang paling sering dipengaruhi oleh kesalahan # N / A adalah fungsi pencarian klasik, termasuk VLOOKUP, HLOOKUP, LOOKUP, dan MATCH.
Cara terbaik untuk mencegah kesalahan # N / A adalah memastikan nilai pencarian dan tabel pencarian sudah benar dan lengkap. Jika Anda melihat kesalahan # N / A yang tidak terduga, periksa hal berikut terlebih dahulu:
- Nilai pencarian dieja dengan benar dan tidak berisi karakter spasi tambahan.
- Nilai dalam tabel pencarian dieja dengan benar dan tidak berisi spasi ekstra.
- Tabel pemeta berisi semua nilai yang diperlukan.
- Rentang pencarian yang disediakan untuk fungsi tersebut selesai (yaitu, tidak "memotong" data).
- Lookup value type = lookup table type (yaitu keduanya teks, keduanya angka, dll.)
- Pencocokan (perkiraan vs. tepat) diatur dengan benar.
Catatan: jika Anda mendapatkan hasil yang salah, saat Anda melihat kesalahan # N / A, pastikan Anda telah mengkonfigurasi pencocokan tepat dengan benar. Mode perkiraan kecocokan akan dengan senang hati mengembalikan semua jenis hasil yang sama sekali tidak benar :)
Menjebak kesalahan # N / A dengan IFERROR
Salah satu opsi untuk menjebak kesalahan # N / A adalah fungsi IFERROR. IFERROR dapat dengan baik menangkap kesalahan apa pun dan mengembalikan hasil alternatif.
Dalam contoh yang ditampilkan, kesalahan # N / A muncul di sel F5 karena "es krim" tidak ada di tabel pencarian, yang merupakan rentang bernama "data" (B5: C9).
=VLOOKUP(E5,data,2,0) // "ice cream" is not found
Untuk menangani kesalahan ini, fungsi IFERROR dibungkus di sekitar rumus VLOOKUP seperti ini:
=IFERROR(VLOOKUP(E7,data,2,0),"Not found")
Jika fungsi VLOOKUP mengembalikan kesalahan, fungsi IFERROR "menangkap" kesalahan itu dan mengembalikan "Tidak ditemukan".
Menjebak kesalahan # N / A dengan IFNA
Fungsi IFNA juga dapat menjebak dan menangani kesalahan # N / A secara khusus. Sintaks penggunaannya sama dengan IFERROR:
=IFERROR(VLOOKUP(A1,table,column,0),"Not found") =IFNA(VLOOKUP(A1,table,column,0),"Not found")
Keuntungan dari fungsi IFNA adalah lebih bersifat bedah, hanya menargetkan kesalahan # N / A. Fungsi IFERROR, di sisi lain, akan menangkap kesalahan apapun. Misalnya, meskipun Anda salah mengeja VLOOKUP, IFERROR akan mengembalikan "Tidak ditemukan".
Tidak ada pesan
Jika Anda tidak ingin menampilkan pesan apa pun saat menjebak kesalahan # N / A (yaitu Anda ingin menampilkan sel kosong), Anda dapat menggunakan string kosong ("") seperti ini:
=IFERROR(VLOOKUP(E7,data,2,0),"")
INDEX dan MATCH
Fungsi MATCH juga mengembalikan # N / A saat nilai tidak ditemukan. Jika Anda menggunakan INDEX dan MATCH bersama-sama, Anda dapat menjebak kesalahan # N / A dengan cara yang sama. Berdasarkan contoh di atas, rumus di F5 adalah:
=IFERROR(INDEX(C5:C9,MATCH(E5,B5:B9,0)),"Not found")
Baca lebih lanjut tentang INDEX dan MATCH.
Memaksakan kesalahan # N / A
Jika Anda ingin memaksakan kesalahan # N / A pada lembar kerja, Anda dapat menggunakan fungsi NA. Misalnya, menampilkan # N / A dalam sel saat A1 sama dengan nol, Anda bisa menggunakan rumus seperti ini:
=IF(A1=0, NA())
