Formula umum
=MIN(UNIQUE(range,0,1))
Ringkasan
Untuk menemukan nilai unik minimum dalam satu set data, Anda dapat menggunakan fungsi UNIQUE bersama dengan fungsi MIN. Pada contoh di bawah ini, rumus dalam E5 adalah:
=MIN(UNIQUE(data,0,1))
di mana "data" adalah rentang bernama B5: B14.
Di versi Excel yang lebih lama, Anda bisa menggunakan rumus array berdasarkan fungsi MIN, IF, dan COUNTIF seperti yang dijelaskan di bawah ini.
Penjelasan
Tujuan dalam contoh ini adalah untuk mengembalikan nilai minimum yang unik, yaitu nilai minimum yang hanya muncul sekali dalam data.
Fungsi UNIQUE, yang baru di Excel 365, akan mengembalikan daftar nilai unik dari sekumpulan data. Secara default, ini adalah daftar nilai apa pun yang muncul satu kali atau lebih dalam data.
UNIQUE memiliki argumen ketiga opsional yang disebut "persis_sekali" yang akan membatasi hasil ke nilai yang muncul sekali hanya dalam data sumber. Untuk mengaktifkan fitur ini, argumen harus disetel ke TRUE atau 1.
Bekerja dari dalam ke luar, fungsi UNIQUE dikonfigurasi seperti ini:
UNIQUE(data,0,1)
Untuk array, kami menyediakan data rentang bernama . Untuk argumen by_col, kami menggunakan nol (0), karena kami ingin nilai unik menurut baris, bukan kolom. Terakhir, untuk exact_once, kami menyediakan 1, karena kami hanya menginginkan nilai yang muncul sekali dalam data sumber.
Dikonfigurasi dengan cara ini, UNIQUE mengembalikan 4 nilai yang muncul hanya sekali:
(700;600;500;300) // result from unique
Array ini dikembalikan langsung ke fungsi MIN, yang mengembalikan nilai minimum, 300, sebagai hasil akhir:
=MIN((700;600;500;300)) // returns 300
Rumus array dengan COUNTIF
Jika Anda menggunakan versi Excel tanpa fungsi UNIQUE, Anda dapat menemukan nilai unik minimum dengan rumus array yang didasarkan pada fungsi COUNTIF, MIN, dan IF.
(=MIN(IF(COUNTIF(data,data)=1,data)))
Ini adalah rumus array dan harus dimasukkan dengan control + shift + enter, kecuali di Excel 365.
Bekerja dari dalam ke luar, fungsi COUNTIF digunakan untuk menghasilkan hitungan setiap nilai dalam data seperti ini:
COUNTIF(data,data) // count all values
Karena ada 10 nilai dalam data rentang bernama , COUNTIF mengembalikan larik 10 hasil:
(2;1;1;2;1;2;2;2;1;2)
Larik ini menampung jumlah setiap nilai. Selanjutnya kita menguji array untuk nilai yang sama dengan 1:
(2;1;1;2;1;2;2;2;1;2)=1
Sekali lagi, kami mendapatkan array dengan 10 hasil:
(FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE)
Setiap nilai TRUE sesuai dengan nilai di sumber data yang muncul sekali. Larik ini dikirim langsung ke fungsi IF, yang menggunakannya seperti filter. Hanya nilai dalam data yang terkait dengan TRUE yang dimasukkan ke dalam larik yang dikembalikan oleh IF, semua nilai lainnya adalah FALSE.
(FALSE;700;600;FALSE;500;FALSE;FALSE;FALSE;300;FALSE)
Array ini dikembalikan langsung ke fungsi MIN yang secara otomatis mengabaikan nilai logika dan mengembalikan nilai minimum yang tersisa, 300, sebagai hasil akhir.
