Cara menggunakan fungsi LAMBDA Excel -

Daftar Isi

Ringkasan

Fungsi LAMBDA Excel menyediakan cara membuat fungsi kustom yang bisa digunakan kembali di seluruh buku kerja, tanpa VBA atau makro.

Tujuan

Buat fungsi kustom

Nilai kembali

Seperti yang didefinisikan oleh rumus

Sintaksis

= LAMBDA (parameter,…, perhitungan)

Argumen

  • parameter - Nilai input untuk fungsi tersebut.
  • perhitungan - Perhitungan yang akan dilakukan sebagai hasil dari fungsi. Harus menjadi argumen terakhir.

Versi: kapan

Excel 365

Catatan penggunaan

Dalam pemrograman komputer, LAMBDA mengacu pada fungsi atau ekspresi anonim. Fungsi anonim adalah fungsi yang ditentukan tanpa nama. Di Excel, fungsi LAMBDA menyediakan cara untuk mendefinisikan dan merangkum fungsionalitas rumus tertentu, seperti fungsi Excel. Setelah ditentukan, fungsi LAMBDA dapat dinamai dan digunakan kembali di tempat lain di buku kerja. Dengan kata lain, fungsi LAMBDA adalah cara untuk membuat fungsi kustom.

Salah satu manfaat utama dari fungsi LAMBDA kustom adalah logika yang terkandung dalam rumus hanya ada di satu tempat. Ini berarti hanya ada satu salinan kode untuk diperbarui saat memperbaiki masalah atau memperbarui fungsionalitas, dan perubahan akan secara otomatis menyebar ke semua contoh fungsi LAMBDA di buku kerja. Fungsi LAMBDA tidak memerlukan VBA atau makro.

Contoh 1 | Contoh 2 | Contoh 3

Membuat fungsi LAMBDA

Fungsi LAMBDA biasanya dibuat dan di-debug di bilah rumus pada lembar kerja, lalu dipindahkan ke manajer nama untuk menetapkan nama yang bisa digunakan di mana saja di buku kerja.

Ada empat langkah dasar untuk membuat dan menggunakan formula kustom berdasarkan fungsi LAMBDA:

  1. Verifikasi logika yang akan Anda gunakan dengan rumus standar
  2. Membuat dan menguji versi LAMBDA generik (tanpa nama) dari rumus tersebut
  3. Beri nama dan tentukan formula LAMBDA dengan pengatur nama
  4. Uji fungsi kustom baru menggunakan nama yang ditentukan

Contoh di bawah ini membahas langkah-langkah ini secara lebih rinci.

Contoh 1

Untuk mengilustrasikan cara kerja LAMBDA, mari kita mulai dengan rumus yang sangat sederhana:

=x*y // multiple x and y

Di Excel, rumus ini biasanya menggunakan referensi sel seperti ini:

=B5*C5 // with cell references

Seperti yang Anda lihat, rumusnya berfungsi dengan baik, jadi kami siap untuk melanjutkan membuat rumus LAMBDA generik (versi tanpa nama). Hal pertama yang harus diperhatikan adalah jika rumus membutuhkan input (parameter). Dalam kasus ini, jawabannya adalah "ya" - rumus tersebut memerlukan nilai untuk x, dan nilai untuk y. Setelah itu, kami mulai dengan fungsi LAMBDA, dan menambahkan parameter yang diperlukan untuk input pengguna:

=LAMBDA(x,y // begin with input parameters

Selanjutnya, kita perlu menambahkan perhitungan aktual, x * y:

=LAMBDA(x,y,x*y)

Jika Anda memasukkan rumus pada saat ini, Anda akan mendapatkan #CALC! kesalahan. Ini terjadi karena rumus tidak memiliki nilai input untuk dikerjakan, karena tidak ada lagi referensi sel. Untuk menguji rumusnya, kita perlu menggunakan sintaks khusus seperti ini:

=LAMBDA(x,y,x*y)(B5,C5) // testing syntax

Sintaks ini, di mana parameter disediakan di akhir fungsi LAMBDA dalam kumpulan tanda kurung terpisah, unik untuk fungsi LAMBDA. Ini memungkinkan formula untuk diuji langsung di lembar kerja, sebelum LAMBDA diberi nama. Pada layar di bawah ini, Anda dapat melihat bahwa fungsi LAMBDA generik di F5 mengembalikan hasil yang sama persis dengan rumus aslinya di E5:

Kami sekarang siap menamai fungsi LAMBDA dengan Manajer Nama. Pertama, pilih rumus, * tidak termasuk * parameter pengujian di bagian akhir. Selanjutnya, buka Name Manager dengan shortcut Control + F3, dan klik New.

Dalam dialog Nama Baru, masukkan nama "XBYY", biarkan cakupan disetel ke buku kerja, dan tempelkan rumus yang Anda salin ke dalam area masukan "Mengacu ke".

Pastikan rumus diawali dengan tanda sama dengan (=). Sekarang rumus LAMBDA memiliki nama, ini dapat digunakan di buku kerja seperti fungsi lainnya. Pada layar di bawah rumus di G5, disalin ke bawah, adalah:

Fungsi kustom baru mengembalikan hasil yang sama seperti dua rumus lainnya.

Contoh 2

Dalam contoh ini, kami akan mengonversi rumus untuk menghitung volume bola menjadi fungsi LAMBDA khusus. Rumus umum Excel untuk menghitung volume bola adalah:

=4/3*PI()*A1^3 // volume of sphere

dimana A1 mewakili radius. Layar di bawah ini menunjukkan cara kerja rumus ini:

Perhatikan rumus ini hanya membutuhkan satu input (radius) untuk menghitung volume, jadi fungsi LAMBDA kita hanya membutuhkan satu parameter (r), yang akan muncul sebagai argumen pertama. Berikut rumus yang diubah menjadi LAMBDA:

=LAMBDA(r,4/3*PI()*r^3) // generic lambda

Kembali ke lembar kerja, kami telah mengganti rumus asli dengan versi LAMBDA generik. Perhatikan kami menggunakan sintaks pengujian, yang memungkinkan kami untuk menyambungkan B5 untuk radius:

Hasil dari formula LAMBDA generik sama persis dengan formula aslinya, maka langkah selanjutnya adalah mendefinisikan dan menamai formula LAMBDA ini dengan Name Manager, seperti yang sudah dijelaskan di atas. Nama yang digunakan untuk fungsi LAMBDA dapat berupa nama Excel apa pun yang valid. Dalam kasus ini, kami akan memberi nama rumus "SphereVolume".

Kembali ke lembar kerja, kami telah mengganti formula LAMBDA generik (tanpa nama) dengan versi LAMBDA bernama, dan memasukkan B5 untuk r. Perhatikan bahwa hasil yang dikembalikan oleh fungsi SphereVolume khusus sama persis dengan hasil sebelumnya.

Contoh 3

Dalam contoh ini, kita akan membuat fungsi LAMBDA untuk menghitung kata. Excel tidak memiliki fungsi untuk tujuan ini, tapi Anda bisa menghitung kata dengan sel dengan rumus kustom berdasarkan fungsi LEN dan SUBSTITUTE seperti ini:

=LEN(TRIM(A1))-LEN(SUBSTITUTE(A1," ",""))+1

Baca penjelasan detailnya di sini. Berikut adalah rumus yang bekerja di lembar kerja:

Perhatikan bahwa kita mendapatkan hitungan 1 yang salah ketika rumus diberikan sel kosong (B10). Kami akan mengatasi masalah ini di bawah.

Rumus ini hanya membutuhkan satu masukan, yaitu teks yang berisi kata-kata. Dalam fungsi LAMBDA kami, kami akan menamai argumen ini "teks". Berikut rumus yang diubah menjadi LAMBDA:

=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+1)

Perhatikan "teks" muncul sebagai argumen pertama, dan kalkulasi adalah argumen kedua dan terakhir. Pada layar di bawah ini, kami telah mengganti formula asli dengan versi LAMBDA generik. Perhatikan bahwa kami menggunakan sintaks pengujian, yang memungkinkan kami memasukkan B5 untuk teks:

=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+1)(B5)

Hasil dari formula LAMBDA generik sama dengan formula aslinya, maka langkah selanjutnya adalah mendefinisikan dan menamai formula LAMBDA ini dengan Name Manager, seperti yang telah dijelaskan sebelumnya. Kami akan menamai rumus ini "CountWords".

Di bawah ini, kami telah mengganti formula LAMBDA generik (tanpa nama) dengan versi LAMBDA bernama, dan memasukkan B5 untuk teks. Perhatikan bahwa kami mendapatkan hasil yang persis sama.

Rumus yang digunakan di Pengelola Nama untuk menentukan CountWords adalah sama seperti di atas, tanpa sintaks pengujian:

=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+1)

Memperbaiki masalah sel kosong

Seperti yang disebutkan di atas, rumus di atas mengembalikan hitungan 1 yang salah saat sel kosong. Masalah ini bisa diperbaiki dengan mengganti +1 dengan kode di bawah ini:

=LEN(TRIM(B5))-LEN(SUBSTITUTE(B5," ",""))+(LEN(TRIM(B5))>0)

Penjelasan lengkapnya di sini. Untuk memperbarui rumus LAMDA bernama yang sudah ada, kita perlu lagi menggunakan Manajer Nama:

  1. Buka Pengelola Nama
  2. Pilih nama "CountWords" dan klik "Edit"
  3. Ganti kode "Merujuk ke" dengan rumus ini:
=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+(LEN(TRIM(text))>0))

Setelah Name Manager ditutup, CountWords bekerja dengan benar pada sel kosong, seperti yang terlihat di bawah ini:

Catatan: dengan memperbarui kode sekali di Pengelola Nama, semua contoh rumus CountWords diperbarui sekaligus. Ini adalah manfaat utama dari fungsi kustom yang dibuat dengan LAMBDA - pembaruan formula dapat dikelola di satu tempat.

Artikel yang menarik...