Cara menggunakan fungsi Excel VLOOKUP -

Daftar Isi

Related videos

Ringkasan

VLOOKUP adalah fungsi Excel untuk mencari data dalam tabel yang disusun secara vertikal. VLOOKUP mendukung pencocokan perkiraan dan tepat, dan karakter pengganti (*?) Untuk pencocokan parsial. Nilai pencarian harus muncul di kolom pertama tabel yang diteruskan ke VLOOKUP.

Tujuan

Cari nilai dalam tabel dengan mencocokkan di kolom pertama

Nilai kembali

Nilai yang cocok dari tabel.

Sintaksis

= VLOOKUP (nilai, tabel, col_index, (range_lookup))

Argumen

nilai - Nilai yang akan dicari di kolom pertama tabel.
table - Tabel tempat mengambil nilai.
col_index - Kolom dalam tabel tempat mengambil nilai.
range_lookup - (opsional) TRUE = perkiraan kecocokan (default). FALSE = sama persis.

Versi: kapan

Excel 2003

Catatan penggunaan

VLOOKUP adalah fungsi Excel untuk mendapatkan data dari tabel yang disusun secara vertikal. Nilai pencarian harus muncul di kolom pertama tabel yang diteruskan ke VLOOKUP. VLOOKUP mendukung pencocokan perkiraan dan tepat, dan karakter pengganti (*?) Untuk pencocokan parsial.

V untuk vertikal

Tujuan VLOOKUP adalah mendapatkan informasi dari tabel yang diatur seperti ini:

Menggunakan Nomor pesanan di kolom B sebagai nilai pencarian, VLOOKUP bisa mendapatkan ID Pelanggan, Jumlah, Nama, dan Negara Bagian untuk pesanan apa pun. Misal, untuk mendapatkan nama pelanggan untuk pesanan 1004, rumusnya adalah:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Untuk data horizontal, Anda dapat menggunakan HLOOKUP, INDEX dan MATCH, atau XLOOKUP.

VLOOKUP didasarkan pada nomor kolom

Saat Anda menggunakan VLOOKUP, bayangkan setiap kolom dalam tabel diberi nomor, dimulai dari kiri. Untuk mendapatkan nilai dari kolom tertentu, berikan nomor yang sesuai sebagai "indeks kolom". Misalnya, indeks kolom untuk mengambil nama depan di bawah ini adalah 2:

Nama belakang dan email dapat diambil dengan kolom 3 dan 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP hanya terlihat benar

VLOOKUP hanya dapat melihat ke kanan. Data yang ingin Anda ambil (nilai hasil) bisa muncul di kolom mana pun di sebelah kanan nilai pencarian:

Jika Anda perlu mencari nilai di sebelah kiri, lihat INDEX dan MATCH, atau XLOOKUP.

Pencocokan tepat dan perkiraan

VLOOKUP memiliki dua mode pencocokan, tepat dan perkiraan. Nama argumen yang mengontrol pencocokan adalah " range_lookup ". Ini adalah nama yang membingungkan, karena sepertinya ada hubungannya dengan rentang sel seperti A1: A10. Sebenarnya, kata "range" dalam kasus ini mengacu pada "range of values" - jika range_lookup BENAR, VLOOKUP akan cocok dengan rentang nilai, bukan nilai persisnya. Contoh yang bagus adalah menggunakan VLOOKUP untuk menghitung nilai.

Penting untuk dipahami bahwa range_lookup defaultnya TRUE, yang berarti VLOOKUP akan menggunakan perkiraan pencocokan secara default, yang bisa berbahaya. Setel range_lookup ke FALSE untuk memaksa pencocokan tepat:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Catatan: Anda juga dapat memasukkan nol (0) sebagai ganti FALSE untuk pencocokan tepat.

Benar-benar cocok

Dalam kebanyakan kasus, Anda mungkin ingin menggunakan VLOOKUP dalam mode pencocokan tepat. Ini masuk akal bila Anda memiliki kunci unik untuk digunakan sebagai nilai pencarian, misalnya, judul film dalam data ini:

Rumus dalam H6 untuk mencari Tahun , berdasarkan pada judul film yang sama persis, adalah:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Perkiraan kecocokan

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.