Formula umum
=ADDRESS(MIN(ROW(range)),MIN(COLUMN(range)))
Ringkasan
Untuk mendapatkan alamat sel pertama dalam suatu rentang, Anda dapat menggunakan fungsi ADDRESS bersama dengan fungsi ROW, COLUMN, dan MIN. Dalam contoh yang ditunjukkan, rumus di F5 adalah:
=ADDRESS(MIN(ROW(data)),MIN(COLUMN(data)))
dimana datanya adalah rentang bernama B5: D14.
Penjelasan
Fungsi ADDRESS membuat referensi berdasarkan nomor baris dan kolom tertentu. Dalam hal ini, kami ingin mendapatkan baris pertama dan kolom pertama yang digunakan oleh data rentang bernama (B5: D14).
Untuk menggunakan baris pertama, kita menggunakan fungsi ROW bersama dengan fungsi MIN seperti ini:
MIN(ROW(data))
Karena data berisi lebih dari satu baris, ROW mengembalikan larik nomor baris:
(5;6;7;8;9;10;11;12;13;14)
Array ini langsung menuju ke fungsi MIN, yang mengembalikan angka terkecil:
MIN((5;6;7;8;9;10;11;12;13;14)) // returns 5
Untuk mendapatkan kolom pertama, kami menggunakan fungsi COLUMN dengan cara yang sama:
MIN(COLUMN(data))
Karena data berisi tiga baris, COLUMN mengembalikan array dengan tiga nomor kolom:
(2,3,4)
dan fungsi MIN kembali mengembalikan angka terbesar:
MIN((2,3,4)) // returns 2
Kedua hasil dikembalikan langsung ke fungsi ADDRESS, yang menyusun referensi ke sel di baris 5, kolom 2:
=ADDRESS(5,2) // returns $B$5
Jika Anda menginginkan alamat relatif dan bukan referensi absolut, Anda dapat memberikan 4 untuk argumen ketiga seperti ini:
=ADDRESS(MIN(ROW(data)),MIN(COLUMN(data)),4) // returns B5
Alternatif fungsi CELL
Meskipun tidak jelas, fungsi INDEX mengembalikan referensi, jadi kita bisa menggunakan fungsi CELL dengan INDEX untuk mendapatkan alamat sel pertama dalam rentang seperti ini:
=CELL("address",INDEX(data,1,1))
Dalam hal ini, kami menggunakan fungsi INDEX untuk mendapatkan referensi ke sel pertama dalam rentang dengan memberikan INDEX 1 untuk nomor baris dan 1 untuk nomor kolom, dengan data untuk array:
INDEX(data,1,1) // returns reference to B5
INDEX kemudian mengembalikan referensi ke sel B5, dan kami menggunakan fungsi CELL dengan "alamat", untuk menampilkan alamat.
Catatan: Fungsi CELL adalah fungsi yang mudah menguap yang bisa menyebabkan masalah kinerja di buku kerja yang besar atau kompleks.
