Formula umum
=SUMPRODUCT((holidays>=start)*(holidays<=end))
Ringkasan
Untuk menghitung hari libur yang terjadi antara dua tanggal, Anda dapat menggunakan fungsi SUMPRODUCT.
Dalam contoh yang ditampilkan, rumus di F8 adalah:
=SUMPRODUCT((B4:B12>=F5)*(B4:B12<=F6))
Penjelasan
Rumus ini menggunakan dua ekspresi dalam satu larik di dalam fungsi SUMPRODUCT.
Ekspresi pertama menguji setiap tanggal hari libur untuk melihat apakah lebih besar dari atau sama dengan tanggal mulai di F5:
(B4:B12>=F5)
Ini mengembalikan larik nilai TRUE / FALSE seperti ini:
(FALSE; FALSE; FALSE; FALSE; TRUE; TRUE; TRUE; TRUE; TRUE)
Ekspresi kedua menguji setiap tanggal hari libur untuk melihat apakah kurang dari atau sama dengan tanggal akhir di F6:
(B4:B12<=F6)
yang mengembalikan larik nilai TRUE / FALSE seperti ini:
(TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; TRUE; FALSE)
Perkalian dua larik ini secara otomatis memaksa nilai TRUE / FALSE menjadi satu dan nol, menghasilkan larik yang terlihat seperti ini:
=SUMPRODUCT(((0;0;0;0;1;1;1;1;1))*((1;1;1;1;1;1;1;1;0)))
Setelah perkalian, kita hanya memiliki satu larik seperti ini:
=SUMPRODUCT((0;0;0;0;1;1;1;1;0))
Terakhir, SUMPRODUCT menjumlahkan item dalam larik dan mengembalikan 4.
Liburan hanya di hari kerja
Untuk menghitung hari libur yang terjadi hanya pada hari kerja (Sen-Jum), Anda dapat memperpanjang rumus seperti ini:
=SUMPRODUCT((rng>=F5)*(rng<=F6)*(WEEKDAY(rng,2)<6))
dengan rng adalah rentang yang berisi tanggal hari libur.
